Add shaders

2026-05-19 15:33:18 +02:00
parent 593c2e75b2
commit cd9df45d08
1358 changed files with 2429155 additions and 0 deletions
@@ -0,0 +1,90 @@
+Shader "Enviro/Particles/Additive" {
+Properties {
+	_MainTex ("Particle Texture", 2D) = "white" {}
+	_InvFade ("Soft Particles Factor", Range(0.01,3.0)) = 1.0
+}
+
+Category {
+	Tags { "Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent" "PreviewType"="Plane" }
+	Blend One OneMinusSrcColor
+	ColorMask RGB
+	Cull Off Lighting Off ZWrite Off
+
+	SubShader {
+		Pass {
+		
+			CGPROGRAM
+			#pragma vertex vert
+			#pragma fragment frag
+			#pragma target 2.0
+			#pragma exclude_renderers gles 
+			#pragma multi_compile_particles
+			#pragma multi_compile_fog
+
+			#include "UnityCG.cginc"
+			#include "../../Resources/Shaders/Core/EnviroFogCore.cginc"
+
+			sampler2D _MainTex;
+			fixed4 _TintColor;
+			
+			struct appdata_t {
+				float4 vertex : POSITION;
+				fixed4 color : COLOR;
+				float2 texcoord : TEXCOORD0;
+				UNITY_VERTEX_INPUT_INSTANCE_ID
+			};
+
+			struct v2f {
+				float4 vertex : SV_POSITION;
+				fixed4 color : COLOR;
+				float2 texcoord : TEXCOORD0;
+				UNITY_FOG_COORDS(1)
+				float4 projPos : TEXCOORD2;
+				float3 posWorld : TEXCOORD3;
+				UNITY_VERTEX_OUTPUT_STEREO
+			};
+
+			float4 _MainTex_ST;
+			
+			v2f vert (appdata_t v)
+			{
+				v2f o;
+				UNITY_SETUP_INSTANCE_ID(v);
+				UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(o);
+				o.vertex = UnityObjectToClipPos(v.vertex);
+				o.posWorld = mul(unity_ObjectToWorld, v.vertex);
+				o.projPos = ComputeScreenPos (o.vertex);
+				COMPUTE_EYEDEPTH(o.projPos.z);
+				o.color = v.color;
+				o.texcoord = TRANSFORM_TEX(v.texcoord,_MainTex);
+				UNITY_TRANSFER_FOG(o,o.vertex);
+				return o;
+			}
+
+			UNITY_DECLARE_DEPTH_TEXTURE(_CameraDepthTexture);
+			float _InvFade;
+			
+			fixed4 frag (v2f i) : SV_Target
+			{
+				float sceneZ = LinearEyeDepth (SAMPLE_DEPTH_TEXTURE_PROJ(_CameraDepthTexture, UNITY_PROJ_COORD(i.projPos)));
+
+				#ifdef SOFTPARTICLES_ON
+				float partZ = i.projPos.z;
+				float fade = saturate (_InvFade * (sceneZ-partZ));
+				i.color.a *= fade;
+				#endif
+				
+				half4 col = i.color * tex2D(_MainTex, i.texcoord);
+				col.rgb *= col.a;
+				UNITY_APPLY_FOG_COLOR(i.fogCoord, col, fixed4(0,0,0,0)); // fog towards black due to our blend mode
+
+				//half linear01Depth = LinearEyeDepth(i.projPos.z);
+				float4 fog = TransparentFog(col,i.posWorld,i.projPos.xy,sceneZ);
+				fog.rgb *= col.rgb;
+				return fog;
+			}
+			ENDCG 
+		}
+	} 
+}
+}