Add shaders

Sources/Shaders/Fire Plume.shader

@@ -0,0 +1,102 @@
+// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'
+
+Shader "Ian's Fire Pack/Fire Plume" {
+Properties {
+	_TintColor ("Tint Color", Color) = (0.5,0.5,0.5,0.5)
+	_MainTex ("Smoke", 2D) = "white" {}
+	_Overlay ("Fire", 2D) = "black" {}
+	_Ramp ("Fade Mask", 2D) = "white" {}
+	_FadeAmount ("Fire Fade Strength", Range(1, 8.0)) = 1.0
+	_InvFade ("Soft Particles Factor", Range(0.01,3.0)) = 1.0
+}
+
+Category {
+	Tags { "Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent" }
+	Blend SrcAlpha OneMinusSrcAlpha
+	ColorMask RGB
+	Cull Off Lighting Off ZWrite Off
+
+	SubShader {
+		Pass {
+		
+			CGPROGRAM
+			#pragma vertex vert
+			#pragma fragment frag
+			#pragma multi_compile_particles
+			#pragma multi_compile_fog
+			
+			#include "UnityCG.cginc"
+
+			sampler2D _MainTex;
+			sampler2D _Overlay;
+			sampler2D _Ramp;
+			fixed4 _TintColor;
+
+			float fadeValue (float value, float amount) {
+				return value*amount - amount + 1;
+			}
+			
+			struct appdata_t {
+				float4 vertex : POSITION;
+				fixed4 color : COLOR;
+				float2 texcoord : TEXCOORD0;
+			};
+
+			struct v2f {
+				float4 vertex : SV_POSITION;
+				fixed4 color : COLOR;
+				float2 texcoord : TEXCOORD0;
+				UNITY_FOG_COORDS(1)
+				#ifdef SOFTPARTICLES_ON
+				float4 projPos : TEXCOORD2;
+				#endif
+			};
+			
+			float4 _MainTex_ST;
+
+			v2f vert (appdata_t v)
+			{
+				v2f o;
+				o.vertex = UnityObjectToClipPos(v.vertex);
+				#ifdef SOFTPARTICLES_ON
+				o.projPos = ComputeScreenPos (o.vertex);
+				COMPUTE_EYEDEPTH(o.projPos.z);
+				#endif
+				o.color = v.color;
+				o.texcoord = TRANSFORM_TEX(v.texcoord,_MainTex);
+				UNITY_TRANSFER_FOG(o,o.vertex);
+				return o;
+			}
+
+			sampler2D_float _CameraDepthTexture;
+			float _InvFade;
+			float _FadeAmount;
+			
+			fixed4 frag (v2f i) : SV_Target
+			{
+				#ifdef SOFTPARTICLES_ON
+				float sceneZ = LinearEyeDepth (SAMPLE_DEPTH_TEXTURE_PROJ(_CameraDepthTexture, UNITY_PROJ_COORD(i.projPos)));
+				float partZ = i.projPos.z;
+				float fade = saturate (_InvFade * (sceneZ-partZ));
+				i.color.a *= fade;
+				#endif
+
+				float fireValue = pow(tex2D(_Overlay, i.texcoord).r, (1.0 - i.color.r)*_FadeAmount + 0.7) * i.color.r;
+
+				fixed4 ramp = tex2D(_Ramp, fixed2(fireValue, 0.5));
+				ramp.a = fireValue;
+
+				fixed4 smoke = tex2D(_MainTex, i.texcoord);
+				smoke.a *= i.color.g;
+
+				fixed4 col = _TintColor * smoke + _TintColor.a * ramp;
+
+				col.a *= i.color.a;
+				UNITY_APPLY_FOG(i.fogCoord, col);
+				return col;
+			}
+			ENDCG 
+		}
+	}	
+}
+}